3,5 Meterband RX / TX?

/*
  Lib: PLL SAA1057
  Version: 1.0.6
  Date: 2024/05/28
  Original Author: Junon M modified by Retroman
  Hardware: Arduino Uno or Nano controlled by serial port
  Modified on 2024/11/07 for FM transmitter usage, Frequency will be stored and read from EEPROM
*/

#include <EEPROM.h>
#include "SAA1057.h"

const char *VERSION = "1.0.6";
const int EEPROM_FREQ_ADDR = 0;
const float DEFAULT_FREQUENCY = 108.0f;
const float MIN_FREQUENCY = 80.f;
const float MAX_FREQUENCY = 110.f;

float Frequency = DEFAULT_FREQUENCY;
float IF_Frequency = 0;
float lastSavedFrequency = 0.0f;

const uint16_t FAST_TUNE = CP_023;
const uint16_t SLOW_TUNE = CP_007;

const int SAA_CLOCK_PIN = 10;
const int SAA_DATA_PIN  = 11;
const int SAA_DLEN_PIN  = 12;

SAA1057 pll;

void setup() {
  Serial.begin(115200);
  Serial.print("PLL SAA1057\nVersion: " + String(VERSION) + "\n\n");
  pll.begin(SAA_CLOCK_PIN, SAA_DATA_PIN, SAA_DLEN_PIN);

  loadFrequency();  // Load the frequency from EEPROM or set to default

  lastSavedFrequency = Frequency;

  pll.clear(0xFFFF, 0);
  pll.set(T_IN_LOCK_CNT, T_SHL);
  pll.set(BRM, BRM_SHL);
  pll.clear(PDM_CLEAR, PDM_SHL);
  pll.clear(SLA, SLA_SHL);
  pll.set(SB2, SB2_SHL);
  pll.set(CP_07, CP_SHL);
  pll.clear(REFH, REFH_SHL);
  pll.set(FM, FM_SHL);
  pll.set(WORDB, WORDB_SHL);

  commitConfig();
}

void loop() {
  commandInterpreter();
}

void commitConfig() {
  pll.setFreqShift(IF_Frequency);
  pll.setFrequency(Frequency, FAST_TUNE);
  delay(50);
  pll.setFrequency(Frequency, SLOW_TUNE);

  if (Frequency != lastSavedFrequency) {
    EEPROM.put(EEPROM_FREQ_ADDR, Frequency);
    lastSavedFrequency = Frequency;
    Serial.print("Saving frequency: ");
    Serial.println(Frequency, 2);
  }
}

String Separator(int len) {
  String s = "\n";
  for (int i = 0; i < len; i++) {
    s += "-";
  }
  s += "\n";
  return s;
}

String getCommands() {
  String msg = "\n";
  msg += Separator(60);
  msg += "Frequency is set to " + String(Frequency, 2) + "MHz";
  msg += Separator(60);
  msg += "\nChoose an option:\n";
  msg += "1. Set new Frequency \n";
  msg += Separator(60);
  return msg;
}

void changeParam(String &returned_text, const String menu_label, const String menu_index, String text, float &value, const float min_value, const float max_value, const String unit) {
  static int pos = 0;
  String S = "";

  if (pos == 0) {
    returned_text = menu_index;
    S += Separator(60);
    S += "Enter the desired " + menu_label + " between " + String(min_value, 2) + unit + " and " + String(max_value, 2) + unit;
    Serial.println(S);
    pos++;
  } else {
    float number = text.toFloat();
    if (number >= min_value && number <= max_value) {
      value = number;
      commitConfig();
      pos = 0;
      returned_text = "";
      S += "Response = " + String(number, 2) + unit + getCommands();
      Serial.println("Frequency updated to: " + String(number, 2) + unit);
    } else {
      S = "Error, the value is out of range, please try again!";
    }
    Serial.println(S);
  }
}

void commandInterpreter() {
  static String lastS = "";
  if (Serial.available()) {
    String text = Serial.readStringUntil('\n');
    String S = (lastS != "") ? lastS : text;

    if (S.equalsIgnoreCase("1")) {
      changeParam(lastS, "Frequency", "1", text, Frequency, MIN_FREQUENCY, MAX_FREQUENCY, "MHz");
    } else {
      Serial.println(getCommands());
    }
  }
}

// Function to load frequency from EEPROM or use the default
void loadFrequency() {
  EEPROM.get(EEPROM_FREQ_ADDR, Frequency);
  if (isnan(Frequency) || Frequency < MIN_FREQUENCY || Frequency > MAX_FREQUENCY) {
    Frequency = DEFAULT_FREQUENCY;
    Serial.print("Loading default frequency: ");
  } else {
    Serial.print("Loading saved frequency: ");
  }
  Serial.println(Frequency, 2);  // Show either the default or the saved frequency
}