Ik ben nu al een hele boel uren bezig om dit project van Frits Kieftenbelt op Picbasic.nl na te bouwen met een Pic 16f628 ipv het voorgestelde 16f630.
Ik werk met het programmeerapparaat Velleman K8048 waarvan ik weet dat er problemen zijn (voor 16f628) met de vaste leds RB0-RB5 en de inverse MCLR ingang door vb eerst programeren en dan in de schakeling zetten.
Compilen doe ik met de Proton+ IDE en Assemblen met Winpic met tot nu toe geen enkel probleem.
De nagebouwde van dezelfde auteur RC5-RC6 codes werkt perfect met PIC 16F628.
Kan iemand eens nakijken wat er scheelt in volgend programma?
Het is vereenvoudigd zodat ik de leduitgangen van de Velleman 8048 kan gebruiken zonder bijkomende problemen.
De REM regels zijn zaken van het originele programma of testen die ik deed maar ik laat ze erbij staan.
HELP wil iemand dit eens nakijken?
http://www.uploadarchief.net/files/download/pbp_rec_a4.bas
Dank bij voorbaat
Opabob

Wat werkt er wel/ wat niet?
RA5 is input only. zet deze dus niet op output.

Hello
Ik dacht dat mijn euro was gevallen doordat ik in TrisA de poortA4 als uitgang had ingesteld maar dat is het niet.
Bij het starten blijft de led branden ( ook met een uploadweerstand op invers MCLRE).
Ik heb ook het project van Frits om RC5 code te lezen nagebouwd en dit werkt perfect.
Echter bij het indrukken van een geldige RC5 code reageert de ontvanger niet, ook niet voor pulssturing.
Hierbij mijn laatste aanpassingen maar hou dus rekening dat de remregels komen van het originele programma of probeersels.

http://www.uploadarchief.net/files/download/pbp_rec_a4b.bas

Tot vlug of tot later
Opabob

Zo, hier zijn we terug nadat ze in de garage een onderdeel van mijn lichaam hebben weggenomen ( 1/5 long)maar de rest zou in orde zijn.
Ik zie dat spijtig genoeg nog niemand heeft gereageerd op deze discutie. Ik heb ook de discutie "Robotje bouwen" van Xest gevolgd hetgeen gelijkwaardig is maar waar het eerder gaat over het aantal kanalalen. Ik krijg mijn project niet eens aan de praat ( geen compilatie of programeerfouten maar werk niet.
Groetjes
Opabob.

@ Opabob.

Je hebt mail. :)

Hier een voorbeeld voor het uitlezen van de ontvanger, dit is gedaan met een pic 16F877 dus wel even omzetten. Het is een simpele code maar werkt perfect.



;  Name    : UITLEZING - RC5 CODE 
                             
;  Author  : H.v.Zwieten. 
                                     
;  Notice  : Copyright (c) 2007 
                               
;  Notice  : All Rights Reserved 
                             
;  Date    : 14-2-2007  
                                       
;  Version : 1.0 
                                              
;  Notes   : Afstands bediening (Phillips code - 088) 
                                                
;  Notes   : Leest afstands bediening uit


Device 16F877                         ; processor type

XTAL 10                               ; cristal 10Mhz

Config HS_OSC,_                       ; cristal groter dan 4MHz
       WDT_OFF,_                      ; Watchdog Timer Enable uit
       PWRTE_ON,_                     ; Power-up Timer Enable aan
       BODEN_OFF,_                    ; Brown-out Reset Enable uit
       LVP_OFF,_                      ; Low Voltage Programming uit
       CPD_OFF,_                      ; Memory Code Protection uit
       WRTE_ON,_                      ; Program Memory Write Enable aan
       DEBUG_ON,_                     ; In-Circuit Debugger Mode aan
       CP_OFF                         ; Code Protection uit

ALL_DIGITAL true                      ; alle poorten digitaal

Declare LCD_RSPIN PORTD.2             ; reset display poort D.2
Declare LCD_ENPIN PORTD.3             ; enable display poort D.3
Declare LCD_DTPIN PORTD.4             ; data display poort D.4 t/m D.7

Declare RC5IN_PIN PORTB.0             ; ir ontvanger op poort B.0

Symbol On = 1                         ; 1 is hoog
Symbol off = 0                        ; 0 is laag

Dim rc5_word As Word                  ; variabele RC5 woord
Dim rc5_command As rc5_word.LowByte   ; variabele RC5 commando
Dim rc5_system As rc5_word.HighByte   ; variabele RC5 systeem

Clear                                 ; wis geheugen 

DelayMS 2000                          ; wacht 2 seconden

Cls                                   ; wis display

;poortb  543210                       ; hulpregel poort B 
PORTB = %000000                       ; maak poort B laag
TRISB = %000001                       ; poort B.0 als ingang

start:                                ; begin programma
Repeat                                ; herhaal
rc5_word = RC5In                      ; lees ir ingang
Until rc5_command <> 255              ; waarde 0 t/m 255
Print At 1,1,"systeem"                ; zet text op display
Print At 1,9,Dec rc5_system , "  "    ; zet waarde op display
Print At 2,1,"commando"               ; zet text op display
Print At 2,10,Dec rc5_command , "  "  ; zet waarde op display
GoTo start                            ; terug naar begin

End                                   ; einde programma
 

Hier een voorbeeld voor het bedienen via een afstands bediening met RC_5 code. met de knoppen 1 t/m 0 kan een frequentie gegenereed worden, en met de pijltjes toetsen kan je een relais bedienen.

Door met het eerste programma de code uit te lezen kan je achter de code komen die achter de knoppen zitten.




;  Name    : AFSTANDBEDIEND - RELAIS. 
                                     
;  Author  : H.v.Zwieten. 
                  
;  Notice  : Copyright (c).

;  Notice  : All Rights Reserved.
                               
;  Date    : 14-2-2008 
                                        
;  Version : 1.0 
                                             
;  Notes   : Bediening via ir afstands bediening.
                                                   
;  Notes   : Relais uitgang plus frequentie uitgang.                                                  


Device 16F628A                       ; processor type

Config INTRC_OSC_NOCLKOUT,_          ; Interne oscillator geen clocksignaal
       WDT_OFF,_                     ; WatchDog Timer uitgeschakeld
       PWRTE_ON,_                    ; Power-up Timer Enable ingeschakeld
       LVP_OFF,_                     ; Low Voltage Programming uitgeschakeld
       MCLRE_OFF                     ; Externe Master Reset Enable uitgeschakeld

ALL_DIGITAL true                     ; alle poorten digitaal

Declare RC5IN_PIN PORTA.1            ; ir ontvanger op poort A.1 (pin - 18)

Declare CCP1_PIN PORTB.3             ; pwm 1 frequentie op poort B.3 (pin - 9) 

Symbol On = 1                        ; 1 is hoog
Symbol off = 0                       ; 0 is laag

Symbol uitgang_1 = PORTB.0           ; relais uitgang op poort B.0 (pin - 6) 

Dim rc5_word As Word                 ; variabele RC5 woord
Dim rc5_command As rc5_word.LowByte  ; variabele RC5 commando
Dim rc5_system As rc5_word.HighByte  ; variabele RC5 systeem

Clear                                ; wis geheugen 

DelayMS 1000                         ; wacht 1 seconden

;poorta  76543210                    ; hulpregel poort A
TRISA = %11111111                    ; poort A als ingang (ir ontvanger op A.1)

;poortb  76543210                    ; hulpregel poort B
TRISB = %00000000                    ; poort B als uitgang 
                                     ; (relais op B.0 en frequentie op B.3)

uitgang_1 = off                      ; uitgang 1 is uit
HPWM 1,0,0                           ; frequentie is 0

start:                               ; start programma
  Repeat                             ; herhaal
  rc5_word = RC5In                   ; lees ir ingang
  Until rc5_command <> 255           ; waarde tussen 0 t/m 255
  ; als systeem is waar en commando is waar dan voer opdracht uit
  If rc5_system = 0 And rc5_command = 32 Then GoTo relais_aan
  If rc5_system = 0 And rc5_command = 33 Then GoTo relais_uit
  If rc5_system = 0 And rc5_command = 1 Then GoTo frequentie_1
  If rc5_system = 0 And rc5_command = 2 Then GoTo frequentie_2
  If rc5_system = 0 And rc5_command = 3 Then GoTo frequentie_3
  If rc5_system = 0 And rc5_command = 4 Then GoTo frequentie_4
  If rc5_system = 0 And rc5_command = 5 Then GoTo frequentie_5
  If rc5_system = 0 And rc5_command = 6 Then GoTo frequentie_6
  If rc5_system = 0 And rc5_command = 7 Then GoTo frequentie_7
  If rc5_system = 0 And rc5_command = 8 Then GoTo frequentie_8
  If rc5_system = 0 And rc5_command = 9 Then GoTo frequentie_9
  If rc5_system = 0 And rc5_command = 0 Then GoTo frequentie_0
  
GoTo start                           ; ga naar begin programma

relais_aan:                          ; sub programma
  uitgang_1 = On                     ; relais is aan
GoTo start                           ; ga naar begin programma

relais_uit:                          ; sub programma
  uitgang_1 = off                    ; relais is uit
GoTo start                           ; ga naar begin programma

frequentie_0:                        ; sub programma
  HPWM 1,0,0                         ; frequentie is 0Khz
GoTo start                           ; ga naar begin programma
                                    
frequentie_1:                        ; sub programma
  HPWM 1,127,500                     ; frequentie is 0.5Khz
GoTo start                           ; ga naar begin programma

frequentie_2:                        ; sub programma
  HPWM 1,127,1000                    ; frequentie is 1Khz
GoTo start                           ; ga naar begin programma

frequentie_3:                        ; sub programma
  HPWM 1,127,1500                    ; frequentie is 1.5Khz
GoTo start                           ; ga naar begin programma

frequentie_4:                        ; sub programma
  HPWM 1,127,2000                    ; frequentie is 2Khz
GoTo start                           ; ga naar begin programma

frequentie_5:                        ; sub programma
  HPWM 1,127,2500                    ; frequentie is 2.5Khz
GoTo start                           ; ga naar begin programma

frequentie_6:                        ; sub programma
  HPWM 1,127,3000                    ; frequentie is 3Khz
GoTo start                           ; ga naar begin programma

frequentie_7:                        ; sub programma
  HPWM 1,127,3500                    ; frequentie is 3.5Khz
GoTo start                           ; ga naar begin programma

frequentie_8:                        ; sub programma
  HPWM 1,127,4000                    ; frequentie is 4Khz
GoTo start                           ; ga naar begin programma

frequentie_9:                        ; sub programma
  HPWM 1,127,4500                    ; frequentie is 4.5Khz
GoTo start                           ; ga naar begin programma

End                                  ; einde programma

Zo heb je een voorbeeld van hoe het kan, het zal nog wel anders kunnen denk, maar dit werkt goed zo (tenminste bij mij wel)

Hoop dat het een beetje duidelijk is zo.

[Bericht gewijzigd door Henry S. op (0%)]

Hello,
Ik hoop dat ik met dezelfde discussie nog even verder kan of moet ik een nieuwe openen met dezelfde gegevens?

In eerste instantie werkte het project van Lambiek niet maar met een hint van hemzelf ( uitwendige oscillator; kristals gebruiken) doet ie het wel.Het project siert door zijn eenvoud en duidelijkheid maar echter één nadeel,het is een latch ( toets 1,uitgang 1 aan _ toets 2, uitgang 1 uit). Voor het sturen van een motortje heb je echter een puls nodig ( als je de toets lost moet de uitgang 0 worden). Dit bleek niet zomaar ( knip) met dit programma te gaan.
Daarom was ik toch terug eens gaan kijken naar het programma van Fritz Kieftenbeld ditmaal ook met een uitwendig kristal van 4 Mhz.
echter zonder resultaat. De led werkt, er is uitgang op de TSOP maar geen enkele poortuitgang reageert.

Is er niemand die mijn bovenstaand probleem ( post van 30 maart met bijhoren programma in het uploadarchief) eens wil nakijken?
Alleszins,
Dank bij voorbaat.
Opabob.

Als de code van Lambiek werkt op de 16f628, dan is deze vrij eenvoudig om te schrijven naar pulsen:

Op 10 april 2010 13:47:03 schreef Lambiek:


  ; Enorme knip uit stuk hierboven

  ; als systeem is waar en commando is waar dan voer opdracht uit
  If rc5_system = 0 And rc5_command = 32 Then GoTo puls_0
  If rc5_system = 0 And rc5_command = 33 Then GoTo puls_1
  If rc5_system = 0 And rc5_command = 1 Then GoTo puls_2
  If rc5_system = 0 And rc5_command = 2 Then GoTo puls_3
  ; En de de rest van de Frequentie goto's uiteraard ook vervangen
  If rc5_system = 0 And rc5_command = 3 Then GoTo frequentie_3
  If rc5_system = 0 And rc5_command = 4 Then GoTo frequentie_4
  If rc5_system = 0 And rc5_command = 5 Then GoTo frequentie_5
  If rc5_system = 0 And rc5_command = 6 Then GoTo frequentie_6
  If rc5_system = 0 And rc5_command = 7 Then GoTo frequentie_7
  If rc5_system = 0 And rc5_command = 8 Then GoTo frequentie_8
  If rc5_system = 0 And rc5_command = 9 Then GoTo frequentie_9
  If rc5_system = 0 And rc5_command = 0 Then GoTo frequentie_0
  
GoTo start                           ; ga naar begin programma

puls_0:                          ; sub programma
  uitgang_0 = On                     ; relais is aan
  sleep 1;
  uitgang_0 = Off                     ; relais is aan

GoTo start                           ; ga naar begin programma

puls_1:                              ; sub programma
  uitgang_1 = On                     ; relais is aan
  sleep 1;
  uitgang_1 = Off                     ; relais is aan

GoTo start                           ; ga naar begin programma

// En bovenstaande instructies ook uitbreiden.

End                                  ; einde programma

@ Opabob.

Het kan nog eenvoudiger, zal nog een paar voorbeelden geven.

En ik heb geprobeerd als je een knop indrukt dat een uitgang net zolang hoog blijft als dat de knop ingedrukt is, maar dat gaat niet.
Het kan eventueel wel met een reset functie.

Hier onder nog een voorbeeld, en dit werkt goed.
Het eerste voorbeeld zijn zes verschillende plus lengte's, en twee pwm waarde's.
En met de nul knop kan je de pwm waarde's op nul zetten.


'*  Name    : IR_RC5 - TEST.                                    
'*  Author  : H.van Zwieten.                                    
'*  Notice  : Copyright (c) 2010 H.v.Z.                         
'*          : All Rights Reserved                               
'*  Date    : 16-4-2010                                         
'*  Version : 1.0                                               
'*  Notes   :                                                   
                                                                                                                 

Device 16F877                         ; processor type

XTAL 10                              ; cristal 10Mhz

Config HS_OSC,_                      ; cristal groter dan 4MHz
       WDT_OFF,_                     ; Watchdog Timer Enable uit
       PWRTE_ON,_                    ; Power-up Timer Enable aan
       BODEN_OFF,_                   ; Brown-out Reset Enable uit
       LVP_OFF,_                     ; Low Voltage Programming uit
       CPD_OFF,_                     ; Memory Code Protection uit
       WRTE_ON,_                     ; Program Memory Write Enable aan
       DEBUG_ON,_                    ; In-Circuit Debugger Mode aan
       CP_OFF                        ; Code Protection uit

ALL_DIGITAL true                     ; alle poorten digitaal

Declare RC5IN_PIN PORTB.0            ; ir ontvanger op poort B.0
Declare CCP1_PIN  PORTC.2            ; hpwm uitgang op poort C.2

Symbol On = 1                        ; 1 is hoog
Symbol off = 0                       ; 0 is laag

Symbol uit_1 = PORTA.0               ; puls uitgang op poort A.0
Symbol uit_2 = PORTA.1               ;           ,,          A.1
Symbol uit_3 = PORTA.2               ;           ,,          A.2
Symbol uit_4 = PORTA.3               ;           ,,          A.3
Symbol uit_5 = PORTA.5               ;           ,,          A.5
Symbol uit_6 = PORTE.0               ;           ,,          E.0
Symbol uit_7 = PORTE.1               ;           ,,          E.1
Symbol uit_8 = PORTE.2               ;           ,,          E.2

Dim rc5_code As Byte                 ; variabele rc5 code
Dim rc5_command As rc5_code.LowByte  ; variabele commando

Clear                                ; wis geheugen 

DelayMS 1000                         ; wacht 1 seconden

        ;543210                      ; hulpregel poort B 
PORTB = %000000                      ; maak poort B laag
TRISB = %000001                      ; poort B.0 als ingang

        ;543210                      ; hulpregel poort A
PORTA = %000000                      ; maak poort A laag
TRISA = %000000                      ; poort A als uitgang

        ;210                         ; hulpregel poort E
PORTE = %000                         ; maak poort E laag
TRISE = %000                         ; poort E als uitgang

; verwerk rc5 code, als waar dan

start:                              

  Repeat                             
  rc5_code = RC5In                  
  Until rc5_command <> 255           
  If rc5_command = 1 Then GoSub uitgang_1
  If rc5_command = 2 Then GoSub uitgang_2 
  If rc5_command = 3 Then GoSub uitgang_3
  If rc5_command = 4 Then GoSub uitgang_4
  If rc5_command = 5 Then GoSub uitgang_5
  If rc5_command = 6 Then GoSub uitgang_6
  If rc5_command = 7 Then GoSub uitgang_7
  If rc5_command = 8 Then GoSub uitgang_8
  If rc5_command = 0 Then GoSub reset_pwm
GoTo start                           

uitgang_1:

uit_1 = On
DelayMS 100
uit_1 = off
DelayMS 1000
Return

uitgang_2:

uit_2 = On
DelayMS 200
uit_2 = off
DelayMS 1000
Return

uitgang_3:

uit_3 = On
DelayMS 300
uit_3 = off
DelayMS 1000
Return

uitgang_4:

uit_4 = On
DelayMS 400
uit_4 = off
DelayMS 1000
Return

uitgang_5:

uit_5 = On
DelayMS 500
uit_5 = off
DelayMS 1000
Return

uitgang_6:

uit_6 = On
DelayMS 1000
uit_6 = off
DelayMS 1000
Return

uitgang_7:

HPWM 1,127,5000
Return

uitgang_8:

HPWM 1,50,5000
Return

reset_pwm:

HPWM 1,0,0
Return

End                                 

Voorbeeld twee is een programma voor het bedienen van een motor_regeling.
Met de pijltjes toetsen kan je de draairichting bepalen en de snelheid veranderen.
En met de nul toets kan je de motor stoppen.
Dit programma kan je ook laten werken met alleen het (command) commando, net als het eerste programma.


;  Name    : MOTORREGELING - RC5 - 1 -.
                                     
;  Author  : H.v.Zwieten. 
                  
;  Notice  : Copyright (c) 2008. 

;  Notice  : All Rights Reserved. 
                             
;  Date    : 8-3-2008. 
                                        
;  Version : 1.0. 
                                              
;  Notes   : Motorregelaar bediend met afstandsbediening.
                                                 
;  Notes   : Afstands bediening (Phillips code - 088).

;  Notes   : Draairichting met pijlen links / rechts.

;  Notes   : Snelheid met pijlen omhoog / omlaag.

;  notes   : Stoppen met 0 knop.




Device 16F877                                  ; processor type

XTAL 10                                        ; cristal 10Mhz

ALL_DIGITAL true                               ; alle poorten digitaal

Declare LCD_RSPIN PORTD.2                      ; reset display poort D.2
Declare LCD_ENPIN PORTD.3                      ; enable display poort D.3
Declare LCD_DTPIN PORTD.4                      ; data display poort D.4 t/m D.7

Declare RC5IN_PIN PORTB.0                      ; ir ontvanger op poort B.0

Declare CCP1_PIN PORTC.2                       ; pwm 1 op poort C.2

Symbol On = 1                                  ; 1 is hoog
Symbol off = 0                                 ; 0 is laag

Symbol links  = PORTC.0                        ; links op poort C.0
Symbol rechts = PORTC.1                        ; rechts op poort C.1
Symbol waarde = 10000                          ; pwm frequentie 10Khz

Dim rc5_word As Word                           ; variabele RC5 woord
Dim rc5_command As rc5_word.LowByte            ; variabele RC5 commando
Dim rc5_system As rc5_word.HighByte            ; variabele RC5 systeem

Dim toeren As Byte                             ; variabele toeren 0 T/M 255

Clear                                          ; wis geheugen 

DelayMS 2000                                   ; wacht 2 seconden

Cls                                            ; wis display

;poortc  76543210                              ; hulpregel poort C
TRISC = %00000000                              ; poort C als uitgang

;poortb  543210                                ; hulpregel poort B
TRISB = %000001                                ; poort B.0 als ingang

links  = off                                   ; linksom is uit
rechts = off                                   ; rechtsom is uit
HPWM 1,0,0                                     ; pwm signaal is uit
toeren = 50                                    ; waarde toeren op 50

Print At 1,8,"WELKOM"                          ; zet text op het display
DelayMS 2000                                   ; pauze 2 sec
Print At 2,4,"MOTOR-REGELAAR"                  ; zet text op het display
DelayMS 2000                                   ; pauze 2 sec
Print At 3,7,"IS-KLAAR"                        ; zet text op het display
DelayMS 2000                                   ; pauze 2 sec
Print At 4,5,"VOOR-GEBRUIK"                    ; zet text op het display
DelayMS 2000                                   ; pauze 2 sec
Cls                                            ; wis display

start:                                         ; start programma
  Print At 1,2,"KIES--LINKS-RECHTS"            ; zet text op het display
  Print At 2,5,"OF--SNELHEID"                  ; zet text op het display
  Repeat                                       ; herhaal
  rc5_word = RC5In                             ; lees ir ingang
  Until rc5_command <> 255                     ; waarde tussen 0 t/m 255
  
  ; als rc5 systeem en rc5 commando is waar dan ga naar richting of snelheid
  
  If rc5_system = 0 And rc5_command = 17 Then GoTo links_om
  If rc5_system = 0 And rc5_command = 16 Then GoTo rechts_om
  If rc5_system = 0 And rc5_command = 32 Then GoTo snelheid_omhoog
  If rc5_system = 0 And rc5_command = 33 Then GoTo snelheid_omlaag
  If rc5_system = 0 And rc5_command = 0  Then GoTo motor_stop
  
GoTo start                                     ; terug naar start

links_om:                                      ; richting motor
  links = On                                   ; motor linknsom is aan
  rechts = off                                 ; motor rechtsom is uit
  Print At 3,4,"MOTOR--LINKSOM"                ; zet text op het display
GoTo start                                     ; terug naar start

rechts_om:                                     ; richting motor
  rechts = On                                  ; motor rechtsom is aan
  links = off                                  ; motor linknsom is uit
  Print At 3,4,"MOTOR-RECHTSOM"                ; zet text op het display
GoTo start                                     ; terug naar start

snelheid_omhoog:                               ; instelling snelheid omhoog 
  toeren = toeren + 5                          ; verhogen toerental
  If toeren = 255 Then toeren = toeren - 5     ; als waar dan toeren hoog
  Print At 4,10,Dec,toeren," "                 ; zet text op het display
  HPWM 1,toeren,waarde                         ; pwm toeren plus frequentie
GoTo start                                     ; terug naar start

snelheid_omlaag:                               ; instelling snelheid omlaag
  toeren = toeren - 5                          ; verlagen toerental
  If toeren = 15 Then toeren = toeren + 5      ; als waar dan toeren laag
  Print At 4,10,Dec,toeren," "                 ; zet text op het display
  HPWM 1,toeren,waarde                         ; PWM toeren plus frequentie
GoTo start                                     ; terug naar start

motor_stop:                                    ; noodstop
  HPWM 1,0,0                                   ; pwm toeren nul frequentie nul
  toeren = 50                                  ; toeren op 50
  links = off                                  ; motor linknsom is uit
  rechts = off                                 ; motor rechtsom is uit
  Cls                                          ; wis display
  DelayMS 1000                                 ; pauze 1 sec
GoTo start                                     ; terug naar start

End                                            ; einde programma

Hello
Al deze voorstellen hebben hun eigen doelstelling; een azpparaat aan of uit zetten, een motor sturen enz..
Ik zoek echter een robotsturing met een 16-tal bevelen.
Elk bevel stuurt een H-brug ( of servomotor) en moet dus stoppen wanneer ik de toets of joystck loslaat. Dan nog gezw<egen voor meerdere kanalen voor voor links of achter rechts.
Ik ben echt gegeneerd tegenover mensen die mij hier willen helpen vooral Lambiek!!!
Toets 1 drukken Uitgang 1 aan
Toets 1 loslaten Uitgang 1 uit
Toets 2 drukken Uitgang 2 aan
Toets 2 loslaten Uitgang 2 uit

enz....

Ja opabob, ik snap wat je bedoeld maar dat gaat niet.
heb van alles geprobeerd als je een knop indrukt wordt er een bitje geset en die zal toch echt gereset moeten worden, en dat gaat niet anders als met de toggle functie tenminste als je het met de zelfde knop wil doen. Of je moet één knop houden voor de reset bv de 0 knop.

Maar wat is er mis mee om twee keer op de knop te drukken, drukken aan drukken uit ik bestuur er ook motoren mee op deze manier.

En meerdere commando's tegelijk versturen gaat toch ook niet op deze manier, de pic zal toch eerst de ene code moeten verwerken voordat je een andere code kan versturen.

Dus ik weet het niet, misschien heeft iemand anders wel een idee.

Ik kan het verhaal niet helemaal volgen hoor (ben nog een noob)
Maar is het niet zo dat de afstandsbediening zijn code blijft zenden zolang je de knop vast houd?
Dan laat je de pic even een bitje setten, en als de knop los gelaten wordt, dat dan door een miniscuul timertje het bitje daarna weer te resetten??
Misschien een oplossing?

Ik heb niet alle antwoorden op de vraag van Opabob doorlezen maar je kunt niet zomaar de 16F630 vervangen door een 16F628A met interne oscillator om de simpele reden dat je de interne oscillator van de 16F628A niet kunt kalibreren.
Grote kans dus dat de 16F628A niet optimaal loopt op zijn interne oscillator, maarja, kalibreren kan dus niet bij dit type PIC.

Dat het andere project van mij (RC5-RC6 transceiver) wél wil met een 16F628A komt omdat dát project op een kristal draait...

@Frits; Hello,ik had u juist over dit onderwerp een mail verstuurd.
Het is juist omgekeerd, uw project om de code uit te lezen op een LCD scherm werkt perfect met 16f628 zonder extern kristal. Het is echter uw project 10 uitgangen of meer sturen met RC5 afstandbediening zelfs met uitwendig kristal maar met een 16f628 ipv het door u voorgestelde 16f630 doet het niet.
Kan je mijn gegevens( verbeteingen; aanpassingen) op de mail eens nakijken zie link uploadarchief en mij aub iets laten weten.
Hartelijk dank
Opabob.

Hallo OpaBob

Helaas kan ik je niet helpen
Ik volg dit item op de voet en vele andere met mij
daarom hoop ik dat je met een oplossing komt op dit forum
en niet verder gaat per mail.

Hans

Hoi,

even een vraag als buitenstaander (heb geen picbasic documentatie): wat doet RC5In in onderstaand stukje code?

Repeat                                       ; herhaal
  rc5_word = RC5In                             ; lees ir ingang
  Until rc5_command <> 255                     ; waarde tussen 0 t/m 255

Als een toets van de afstandsbediening wordt ingedrukt, geeft de functie RC5In eenmalig de RC5 code terug en daarna steeds 255 totdat de toets is losgelaten en weer opnieuw wordt ingedrukt (te zien aan het toggle bit in de RC5 data)?
Of geeft de functie steeds de RC5 code terug totdat de toets op de afstandsbediening wordt losgelaten.

Als de functie werkt zoals de eerste beschrijving zou je op de betreffend input kunnen kijken of er nog steeds 'activiteit' is of iets dergelijks. Als er geen activiteit meer is doe dan de stop actie.
Als de functie werkt op de 2e manier, dan kun je wachten op de eerste '255' en dan de stop actie doen.

@Fredjuhh: De meeste AB-protocollen hebben een aparte code voor een herhalende toets. Dat is dus niet hetzelfde als het telkens opnieuw sturen van de ingedrukte toets.

@Opabob
Ik probeer te volgen wat u wilt bereiken, maar dat lukt niet erg.
Een robot, bediend met een AB, die een aantal kunstjes (lees instructies uitvoeren) kan. Verder kom ik niet.
Het is mij niet duidelijk hoe de knoppen de robot moeten besturen.
Hiervoor is in principe een aantal mogelijkheden te bedenken:
1 - een knop indrukken start de instructie, nog een keer indrukken stopt de instructie
2 - een knop indrukken start de instructie, die houdt pas op als de knop is losgelaten (dan kan er maar 1 instructie tegelijkertijd worden uitgevoerd!)
3 - een knop indrukken start de instructie, een andere knop indrukken stopt de eerste instructie en start de nieuwe
4 - een knop indrukken start de instrucite, een andere knop indrukken start een tweede instructie maar stopt de eerste niet en er is 1 knop die alle instructies stopt
5 - elke instructie heeft een aparte knop voor het starten en een andere aparte knop voor het stoppen

Omdat elke mogelijkheid een andere opbouw van het programma tot gevolg heeft is het heel moeilijk om de opgestuurde code te beoordelen. Ik weet nl niet wat nou precies de bedoeling is.

Wij kunnen prima helpen als we iets meer weten dan dat er in de code staat. Dus een zgn functionele beschrijving van WAT de zender en de ontvanger moeten kunnen. Het HOE komt dan later wel.

Dit zegt Opabob:

Elk bevel stuurt een H-brug ( of servomotor) en moet dus stoppen wanneer ik de toets of joystick loslaat

Dus dan voldoet deze : "2 - een knop indrukken start de instructie, die houdt pas op als de knop is losgelaten (dan kan er maar 1 instructie tegelijkertijd worden uitgevoerd!)"

Volgens mij is dat de bedoeling ;)
Zie ook :

Toets 1 drukken Uitgang 1 aan
Toets 1 loslaten Uitgang 1 uit
Toets 2 drukken Uitgang 2 aan
Toets 2 loslaten Uitgang 2 uit

Wat ik dus begrijp, is dus als je een knop van de ab ingedrukt houd dat hij dan niet de code blijft zenden? Ik heb nu even gekeken bij b.v. geluid harder/zachter, en i.d.d. als je daar je hand een keer tussen stopt, dan gaat het geluid ook niet meer harder/zachter, dus er zit "iets" meer achter.

Maar, als je dan toch een ir ontvanger hebt en lcd, dan zou je naar mijn idee gewoon een code uit kunnen lezen toch? Want de ab blijft toch op de een of andere manier zenden zolang de knop ingedrukt blijft.
Misschien dat hij b.v. eerst even een 5 zendt en daarna telkens de 15???(om maar eens een getalletje te noemen)
Want als ik dan naar het lampje op de tv kijk, zie ik die gewoon blijven knipperen als er een knop is ingedrukt, dus erg moeilijk kan het niet zijn lijkt me... Heb helaas geen ir led om het uit te gaan proberen...
Maar goed, ik weet niet precies hoe het werkt ;) Maar volgens mij komen we daar wel uit toch?? ;)

@ Habro

Helaas kan ik je niet helpen
Ik volg dit item op de voet en vele andere met mij
daarom hoop ik dat je met een oplossing komt op dit forum
en niet verder gaat per mail.
Hans.

Hans, als je geinteresseerd bent in dit onderwerp, raad ik je aan eens een kijkje te gaan nemen op de projecten van Picbasic.Nl.
Het is Frits Kieftenbelt ( Honourable member bij CO)die deze projecten uitgewerkt heeft. Dus die email was een vriendelijk tikje op zijn schouder met de vraag, bekijk mijn probleem eens?
Hij werkt met een Pic 16F630 dewelke ik niet bezit en zegt zelf dat dit kan gewijzigd worden en geef daarbij mijn verbeterde versie door in het uploadarchief om eens na te kijken want(zonder compile of programeerfouten in Proton en Winpic met Velleman 8048) HET WERK NIET!
Nog een hint: de ontwerpen van Lambiek doen het wel in hun eigen doelstelling en hij geeft een zeer degelijke en eenvoudige ondersteuning voor beginnelingen zoals wij.

@ hadv en Fredjuhh
Het gaat inderdaad over " 2 " om het voorlopig eenvoudig te houden; Ik ga al tevreden zijn als ik IETS werkend krijg in die toets in_toets uit voor een tiental bevelen met als resultaat uitgang aan_Uitgang uit want stilaan......

Later kan ik dan nog zien of het mogelijk is zoals bij TV door blijven op de toets te drukken het geluid ( hier motorsnelheid) te vermeerderen of verminderen.

Ik denk dat ik eerst nog een paar zaken moet oplossen ivm oscillator en programeerapparaat(Velleman 8048) die uit ondervinding een belangrijke rol spelen in het geheel. Uitleg ook later.
H E E L graag reactie
Opabob.

Want als ik dan naar het lampje op de tv kijk, zie ik die gewoon blijven knipperen als er een knop is ingedrukt, dus erg moeilijk kan het niet zijn lijkt me...

Als je op een RC5 (Philips) afstandbediening een knop indrukt gaat 'ie een code uitzenden. Deze code bestaat uit 3 delen: een getal wat weergeeft welke knop is ingedrukt (bv 0-9, harder-zachter, ...), een getal wat weergeeft voor welk instrument de code bestemd is (TV, Video, CD, ...) en een toggle bitje.
Zolang je de knop ingedrukt houdt zal de afstandbediening de code blijven herhalen (te zien aan het knipperen van het ledje van de TV). Als je de knop loslaat en weer indrukt verandert het toggle bitje van waarde. Op deze manier kan de ontvanger zien dat het knopje 2x is ingedrukt (bv als je kanaal 11 intoetst). Daarom krijg je ook geen twee keer '1' als je je hand even voor de afstandbediening houdt.

Of het makkelijk te realiseren is om een actie te doen zolang er een knop is ingedrukt hangt af van de manier waarop de RC5In functie geïmplementeerd is.

Op 20 april 2010 09:58:12 schreef Opabob:
@ hadv en Fredjuhh
Het gaat inderdaad over " 2 " om het voorlopig eenvoudig te houden; Ik ga al tevreden zijn als ik IETS werkend krijg in die toets in_toets uit voor een tiental bevelen met als resultaat uitgang aan_Uitgang uit want stilaan......

Keuze 2 dus.
Het programma aan de kant van de robot ziet er dan alsvolgt uit.
Het eerste stuk komt rechtstreeks uit het manual (ik heb geen ervaring met RC5in):


Dim RC5_Word as Word
dim MyRc5 as byte
While 1 = 1 ' Create an infinite loop 
  Repeat RC5_Word = RC5In ' Receive a signal from the infrared sensor 
  Until RC5_Command <> 255 ' Keep looking until a valid header found
  Print at 1,1,"System ",Dec RC5_System," " ' Display the System value 
  Print at 2,1,"COMMAND ",Dec RC5_Command," " ' Display the COMMAND value 
  MyRc5 = RC5_Command
  gosub doe_commando
Wend

We hebben in MyRc5 nu (blijkbaar) een geldig commando, daar gaan we mee verder.
Omdat we pas ophouden met deze instructie als de knop is losgelaten ziet dat er, in hoofdlijnen, alsvolgt uit:


doe_commando:

  select MyRc5
  case 1
    gosub subroutine_1
  case 2
    gosub subroutine_2
  case n
    gosub subroutine_n
  endcase
return

subroutine_1:

sr_1:

  repeat
    ; doe de dingen die hier nodig zijn
    ; aan het eind kijken of we door moeten gaan of stoppen
    RC5_Word = RC5In
  until RC5_Command <> MyRC5
    ; doe wat nodig is om de dingen te stoppen
return

De regel RC5_Word = RC5In zit hier om te kijken of er uberhaupt nog een knop is ingedrukt en wacht dus niet zoals de instructie in het begin op een geldige header omdat die niet zal komen als er geen knop is ingedrukt. Ze detecteer je dus "knop uit".

Wat RobHoi hierboven zegt zou ook kunnen worden gebruikt, maar omdat ik niet weet hoe Proton daar mee omgaat kan ik er geen zinnig woord over zeggen. Het zou het programma nog makkelijker kunnen maken.

[Edit]
Hmm, net even zelf gebouwd (ik blijk dus wel een RC5 AB te hebben) en het werkt niet.
De scope er op gehangen en het is mij nu ook duidelijk waarom het niet werkt op deze manier.
Tussen elke pulstrein (die een commando verstuurt) zit een pauze van zo'n 88 msec. Ik ga nog even verder experimenteren...
[Edit2]
Wat zitten experimenteren met delay's en wachten op de RC5In_pin laag, maar het mag allemaal niet baten.
Ik heb ook nog even naar de RC5In routine (assembler) gekeken, maar daar kom ik ook niet echt lekker doorheen.
Ik vrees dat het "wachten tot knop weer los" mij niet lukt met RC5In van Proton. In assembler zal het denk ik wel lukken, maar daar heb ik nu even geen zin in omdat ik het niet zelf nodig heb.

Dat bij het ingedrukt houden van een knop het ontvangerlampje gaat knipperen is heel goed uit te leggen en ook heel makkelijk te programmeren.
Waar het hier om gaat is detecteren dat er een knop is losgelaten. Dat resulteert in een RC5_Command van 255. Maar daar kun je in de software niet op schakelen omdat RC5In vrijwel continu 255 doorgeeft.
Het besturingsmodel van een AB is nu eenmaal gebaseerd op enkelvoudige commando's die worden getriggerd door een knop in te drukken, niet door die knop weer los te laten.
Overigens is de herhaalknop wel makkelijk met RC5In te bouwen, daar hoef je namelijk niets voor te doen.

[Bericht gewijzigd door hadv op (18%)]

Even voort bordurend met wat jij zegt hadv: Als de snelheid niet helemaal belangrijk is bij Opabob, dan zou je daar dus een timertje mee kunnen laten lopen van zeg 0,5Sec de timer laat je telkens resetten als hij de juiste code ontvangt, dus bij een tijd van langer dan 0,5 sec gooi je alles weer uit.
Dan ben je dus de 88mS pause tijd voorbij en een evt. eenmalig verkeerd signaal ook voorbij....
Of denk ik weer te makkelijk?

[Edit]
Ik ben wel nieuwsschierig als je er een lcd aan zou hangen, en dan gaat kijken welke waarde er te voorschijn komen: met andere woorden: probeer dit eens: en vertel dan eens of je er wel getallen uit kunt halen ? Als je hem dus uitleest, kun je ook zien wat en wanneer er wat gebeurt.


Device = 16F877                'WEl de juiste pic instellen ;)
 RC5IN_PIN = PORTC.0                         ' Choose the port and pin for the infrared sensor
 DIM RC5_WORD as WORD                        ' Create a WORD variable to receive the data
 DIM RC5_COMMAND as RC5_WORD.Lowbyte         ' Alias the COMMAND byte to RC5_WORD low byte
 DIM RC5_SYSTEM as RC5_WORD.Highbyte         ' Alias the COMMAND byte to RC5_WORD high byte
 
 ALL_DIGITAL = ON                            ' Make all pins digital mode
 Cls                                         ' Clear the LCD
 While 1 = 1                                 ' Create an infinite loop
  Repeat                     
    RC5_WORD = RC5In                         ' Receive a signal from the infrared sensor
  Until RC5_COMMAND<> 255                    ' Keep looking until a valid header found
  Print at 1,1,"SYSTEM  ",Dec RC5_SYSTEM," "  ' Display the SYSTEM value
  Print at 2,1,"COMMAND ",Dec RC5_COMMAND," " ' Display the COMMAND value
 Wend
[/code=picbasic]

[Bericht gewijzigd door Fredjuhh op (61%)]

Opabob, ik heb je (naar een 16F628A aangepaste) programma eens vluchtig bekeken, maar mijn mening blijft in principe hetzelfde.
Het zijn de tijden die anders zijn.
Onthoud goed, mijn programma maakt geen gebruik van de PICBasic functie RC5IN, maar van een eigen inleesroutine voor RC5.
De DELAYUS tijden zijn daarbij kritisch, dus als de interne oscillator van je 16F628A maar iets uit de pas loopt, dan werkt het al niet meer.

Ik besef me hierbij echter wel dat ik destijds (in de beginperiode dat ik met PICBasic begon heb ik dat programma geschreven) heb ik niet SET_OSCCAL gebruikt maar heb ik een OSCCAL waarde in het programma opgegeven (dat werkte op de 16F630 die ik gebruikte van dat moment), maar is daarmee natuurlijk niet gezegd dat het ook werkt op andere 16F630 PIC's, die kunnen een andere OSCCAL waarde nodig moeten hebben (en dat is dan een kwestie van experimenteren, sorry hiervoor).
Ook een PIC draaiend op een kristal hoeft hierbij dus niet de oplossing te zijn, omdat ik de tijden destijds dus niet "geijkt" heb
(het zou beter zijn geweest als ik het programma toentertijd had ontwikkeld met een PIC met kristal zodat de tijden op alle PIC's zouden werken).

Je zou dus nog kunnen proberen om wat met de DELAYUS tijden te gaan spelen.
Als je echter een 16F630 hebt, hoef je alleen maar met de waarde van OSCCAL te experimenteren, beginnen bij bijvoorbeeld 40 en steeds met 20 ophogen en de PIC weer programmeren en proberen.
Sorry maar wist destijds nog niet van het hoe of wat van SET_OSCCAL (ook al omdat BumbleBee dat toen uitwiste).

Op 20 april 2010 20:31:25 schreef Fredjuhh:
Even voort bordurend met wat jij zegt hadv: Als de snelheid niet helemaal belangrijk is bij Opabob, dan zou je daar dus een timertje mee kunnen laten lopen van zeg 0,5Sec de timer laat je telkens resetten als hij de juiste code ontvangt, dus bij een tijd van langer dan 0,5 sec gooi je alles weer uit.
Dan ben je dus de 88mS pause tijd voorbij en een evt. eenmalig verkeerd signaal ook voorbij....
Of denk ik weer te makkelijk?

[Edit]
Ik ben wel nieuwsschierig als je er een lcd aan zou hangen, en dan gaat kijken welke waarde er te voorschijn komen: met andere woorden: probeer dit eens: en vertel dan eens of je er wel getallen uit kunt halen ? Als je hem dus uitleest, kun je ook zien wat en wanneer er wat gebeurt.


Device = 16F877                'WEl de juiste pic instellen ;)
 RC5IN_PIN = PORTC.0                         ' Choose the port and pin for the infrared sensor
 DIM RC5_WORD as WORD                        ' Create a WORD variable to receive the data
 DIM RC5_COMMAND as RC5_WORD.Lowbyte         ' Alias the COMMAND byte to RC5_WORD low byte
 DIM RC5_SYSTEM as RC5_WORD.Highbyte         ' Alias the COMMAND byte to RC5_WORD high byte
 
 ALL_DIGITAL = ON                            ' Make all pins digital mode
 Cls                                         ' Clear the LCD
 While 1 = 1                                 ' Create an infinite loop
  Repeat                     
    RC5_WORD = RC5In                         ' Receive a signal from the infrared sensor
  Until RC5_COMMAND<> 255                    ' Keep looking until a valid header found
  Print at 1,1,"SYSTEM  ",Dec RC5_SYSTEM," "  ' Display the SYSTEM value
  Print at 2,1,"COMMAND ",Dec RC5_COMMAND," " ' Display the COMMAND value
 Wend
[/code=picbasic][/quote]
Dat is heel erg voorspelbaar: precies de waarden conform het RC5 protocol. Zoals '1' als je op de '1' drukt. Kun je zo op internet opzoeken.

Dus die blijf je in beeld zien? Dan is het toch makkelijk te doen met mijn idee van dat timertje?
;)

[Edit] Dan ga ik in de toekomst ook wel iets met ir doen, ik zie genoeg mogelijkheden ;)

[Bericht gewijzigd door Fredjuhh op (31%)]

Het probleem is dus juist dat je wacht op "knop los", dan krijg je commando 255 en daar heb je geen fluit aan omdat dat ook kan optreden tussen de geldige commando's terwijl je de knop ingedrukt houdt. Zelfs met een timertje, dat heb ik nl al geprobeerd met behulp van delayMS.

[Bericht gewijzigd door hadv op (35%)]