Voorheen heb ik met succes de EEPROM gebruikt in progjes voor de PIC16F684 en PIC12F683.
Ben nu met een waterpompbeveiliging bezig met de 16F913, het hele programma draait al goed, alleen met de EEPROM wil het maar niet lukken. Het programma loopt compleet vast wanneer de eeprom-write routine wordt aangeroepen. Heb de routine al op verschillende manieren herschreven maar het probleem blijft.
Ik hoop dat iemand de fout ziet!
Had hiervoor hetzelfde probleem met de 16F685, heb hem oplaatst aan de kant gegooid, maar daar lag het dus niet aan...
De gebruikte Software: MPLAB 7.52
Programmer: Velleman K8048
Het totale progje is kleiner dan 1kbyte.
De laatst gebruikte eeprom-write routine:
eeWrite BCF PIR1,EEIF
BSF STATUS,RP1 ;
BCF STATUS,RP0 ;Bank 2
MOVF TEMPEEADDR,w ;Data Memory
MOVWF EEADRL ;Address to write
MOVF TEMPEEDATA,w ;Data Memory Value
MOVWF EEDATL ;to write
BSF STATUS,RP0 ;Bank 3
BCF EECON1,EEPGD ;Point to DATA memory
BCF INTCON,GIE
BSF EECON1,WREN ;Enable writes
MOVLW 0x55 ;
MOVWF EECON2 ;Write 55h
MOVLW 0xAA ;
MOVWF EECON2 ;Write AAh
BSF EECON1,WR ;Set WRbit to begin write
BSF INTCON,GIE ;Enable INTs.
BCF STATUS,RP0 ;bank0
BCF STATUS,RP1
btfss PIR1,EEIF ;write finished?
goto $-1 ;no
nop ;
bcf PIR1,EEIF ;yes
bsf STATUS,RP1 ;bank3
bsf STATUS,RP0
BCF EECON1,WREN ;Disable writes
bcf STATUS,RP1 ;bank0
bcf STATUS,RP0
return
Dankzij de MPLAB-simulator de fout gevonden!
Bij deze controller moet blijkbaar bank0 gekozen worden voordat er met een variabele gewerkt wordt. In de voorbeelden in de datasheet doen ze dat dus niet 
Misschien toch maar eens op AVR overstappen 
nieuwe code:
eeWrite bcf PIR1,EEIF ;clear flag
MOVf TEMPEEADDR,w ;Data Memory
BSF STATUS,RP1 ;
BCF STATUS,RP0 ;Bank 2
MOVWF EEADRL ;Address to write
bcf STATUS,RP1 ;Bank 0
MOVF TEMPEEDATA,w ;Data Memory Value
BSF STATUS,RP1 ;Bank 2
MOVWF EEDATL ;to write
BSF STATUS,RP0 ;Bank 3
BCF EECON1,EEPGD ;Point to DATA memory
bcf INTCON,GIE ;Disable interrupts
BSF EECON1,WREN ;Enable writes
MOVLW 0x55 ;
MOVWF EECON2 ;Write 55h
MOVLW 0xAA ;
MOVWF EECON2 ;Write AAh
BSF EECON1,WR ;Set WR bit to begin write
BSF INTCON,GIE ;Enable INTs.
bcf STATUS,RP0 ;bank0
bcf STATUS,RP1
btfss PIR1,EEIF ;write finished?
goto $-1 ;no
nop ;
bcf PIR1,EEIF ;yes
bsf STATUS,RP1 ;bank3
bsf STATUS,RP0
BCF EECON1,WREN ;Disable writes
bcf STATUS,RP1 ;bank0
bcf STATUS,RP0
return
Op 21 april 2007 16:31:14 schreef Zonnepaneeltje:
Dankzij de MPLAB-simulator de fout gevonden!
Bij deze controller moet blijkbaar bank0 gekozen worden voordat er met een variabele gewerkt wordt.
Dat is voor alle 16 PICs zo.
Dus dat kan dus nooit gewerkt hebben op de PIC16F684 en PIC12F683. De makkelijkste manier is om dit soort variabelen tussen adres 0x70 tot 0x80 te zetten, dat is shared memory voor alle banken. (Of gewoon de bankselects goed doen
)
Maar jij gaf in de source niet aan waar die variabelen zaten en een kristallen bol heb ik hier niet.
De variabelen zijn TEMPEEADDR en TEMPEEDATA.
Heb de 16f684-routine even bekeken. Het adres stel ik daar al in voordat ik naar de eewrite-routine spring, en de data neem ik mee in w. Daarom ging het daar dus wel goed 
Die bankselects is trouwens ook iets om gek van te worden. Dat ze dat niet anders opgelost hebben.
Bedankt voor de tip, tussen 0x70 en 0x80 kan het RAM dus zonder bankchanges worden benaderd, scheelt weer code
.
Op 21 april 2007 16:31:14 schreef Zonnepaneeltje:
[...]Misschien toch maar eens op AVR overstappen[...]
Als ik zie wat je daar een lap code voor nodig hebt... Is dat misschien hoe dan ook wel een goed idee 
Maar heeft zo'n AVR-ding uberhaupt wel EEPROM aan boord?

'T is tenslotte een vrij modern stukje techniek 
Vrijwel alle AVR's hebben EEPROM aan boord, en ik zie ook met lede ogen aan hoe omslachtig sommige dingen met een PIC geprogrammeert moeten worden in vergelijking tot AVR's, alhoewel PIC's ook zeker sterke kanten hebben bij bepaalde toepassingen, alleen zie ik ze niet.
Voor verdere info zie atmel site en avrfreaks.net