Ik loop al enkele dagen te klooien met een PIC 16F628A en het lcd-16 display van voti.nl ik werk in de 4 bit modus.
Het initialiseren gaat allemaal goed, maar dan komen de problemen.
sommige karakters krijg ik wel op het scherm, en andere niet. in de afbeelding hier onder staat een rode streep door de karakters die het lcd niet weer wil geven
zoals je ziet eindigen de hoge en lage nibble van de karakters die niet weergegeven worden in binaire notatie op een 1, Als ik simuleer in MPLAB lijkt alles goed te gaan, ik heb ook al een ander MCU geprobeerd maar dat gaf het zelfde probleem.
Voorbeeld: als ik een H naar het scherm stuur 48h (0100 1000) krijg ik een H op het scherm maar als ik een I stuur 49h (0100 1001) krijg ik ook een H op het scherm, en zo gaat het verder met alle karakters.
hier onder mijn code, let niet op schoonheids foutjes, ik ben te veel aan het klooien geweest
list p=16f628A
#INCLUDE <P16F628A.INC>
__CONFIG _INTRC_OSC_NOCLKOUT & _WDT_OFF & _PWRTE_ON & _BODEN_ON & _MCLRE_OFF & _CP_OFF
;###### VARIABELEN ########
cblock 20h
d1 ;DELAY VAR1
d2 ;DELAY VAR2
nib2send ;4 bit nibble voor dateverkeer met lcd
byte2send ;8 bit data voor LCD, wordt later opgesplitst
endc
;$$$$$$ VARIABELEN EIND $$$
EN equ 02h ;poort B2
RS equ 03h ;poort B3
DB4 equ 04h ;poort B4
DB5 equ 05h ;poort B5
DB6 equ 06h ;poort B6
DB7 equ 07h ;poort B7
call longdly ;geef lcd de tijd
clrf PORTA ;zet A poorten uit
clrf PORTB ;zet B poorten uit
call longdly ;geef lcd de tijd
movlw 07h ;0000 0111
movwf CMCON ;zet vergelijkers uit
bsf 03h, RP0 ;selecteer bank 1
movlw 03h ;0000 0011
movwf TRISB ;maak van poort B2:B7 een uitgang
bcf 85h, 01h ;maak van poort A.1 een uitgang
bcf 83h, RP0 ;selecteer bank 0
call funset4bit ;zet de functies op (4 Bit, 2 lijnen, 5x8 font)
call longdly ;vertraging
call disp ;roep display on/off routine op
call longdly ;vertraging
call clr ;maak display leeg
call emode ;stel entry mode in
call longdly
bsf PORTB, RS
movlw 43h
movwf nib2send
call sendnib
swapf nib2send, 1
call longdly
call sendnib
bcf PORTB, RS
call longdly
goto loop
;##### EMODE ENTRY MODE SET ####
emode
nop
bcf PORTB, RS ;maak RS laag
movlw 06h ;0000 0110
movwf nib2send ;(0,0,0,0 0,1,increment,0)
call sendnib ;zet hoogste 4 bit op data lijnen
swapf nib2send, 1 ;omkeren
call sendnib ;zet laagste 4 bit op data lijnen
bsf PORTB, RS ;maak RS hoog
return
;$$$$$$$ EMODE EIND $$$$$$$$$$
;######## CLR ######### Maak display leeg
clr
nop
bcf PORTB, RS ;maak RS laag
movlw 01h ;0000 0001
movwf nib2send ;(0,0,0,0 0,0,0, maak display leeg)
call sendnib ;zet hoogste 4 bits op data lijnen
swapf nib2send, 1 ;omkeren
call sendnib ;zet laagste 4 bits op data lijnen
call longdly ;vertraging
clrf nib2send ;bug voorkomen
bsf PORTB, RS ;maak RS hoog
return
;$$$$$$$$ CLR EIND $$$$$$$
;######## DISP ######### Zet het display aan of uit
disp
nop
bcf PORTB, RS ;maak RS lijn laag
movlw 0Ch ;0000 1110
movwf nib2send ;(0,0,0,0 1, display on, cursor on, blinking off)
call sendnib ;zet hoogste 4 bits op data lijnen
swapf nib2send, 1 ;draai om
call sendnib ;zet laagste 4 bits op data lijnen
bsf PORTB, RS ;maak RS lijn hoog
nop
nop
return
;$$$$$$$$$ DISP EIND $$$$$$$$$$
;######## FUNSET4BIT ########
funset4bit
bcf 83h, RP0 ;selecteer bank 0
movlw 20h ;0010 0000 (selecteer 4 bit modus)
movwf nib2send ;zet data in var om te versturen
bcf PORTB, RS ;maak de RS lijn laag
call sendnib ;roep data transfer functie op
call longdly ;wacht routine
;Omdat De LCD vanaf nu in 4 bit modus werkt moet de function set byte nogmaals verstuurd worden
;ditmaal de volledige 8 bit in 2 keer 4 bit
clrf byte2send ;bug voorkomen
movlw 28h ;0010 1000 instruction set van LCD (4 bit modus, 2 lijns modus)
movwf byte2send ;
call splitbyte ;routine om de byte te splitsen
bsf PORTB, RS ;Maak RS lijn hoog
nop
nop
nop
return
;$$$$$$$$$ FUNSET4BIT EIND $$$$$$$$
;############ SENDNIB ############ HANDELT DATA VERKEER MET LCD AF
sendnib
bcf PORTB, 04h ;Zet data poorten op 0
bcf PORTB, 05h
bcf PORTB, 06h
bcf PORTB, 07h
btfsc nib2send, 07h ;als bit 7 geset is maak poort B7 hoog etc
bsf PORTB, 07h
btfsc nib2send, 06h
bsf PORTB, 06h
btfsc nib2send, 05h
bsf PORTB, 05h
btfsc nib2send, 04h
bsf PORTB, 04h
nop
bsf PORTB, 02h ;maak EN lijn hoog
nop
nop
bcf PORTB, 02h ;maak EN lijn laag
nop
nop
return
;$$$$$$$$$$$ SENDNIB EIND $$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
;########## SPLIT BYTE ############
; -IN: byte2send -OUT: --
splitbyte
clrf nib2send ;bug voorkomen
movf byte2send, 0 ;zet byte2send in W register
movwf nib2send ;zet hoogste 4 bits klaar
call sendnib ;verzend hoogste 4 bits
swapf nib2send, 1 ;draai de nibbles om
call sendnib ;verzend laagste 4 bits
clrf byte2send
clrf nib2send
return
;$$$$$$$$$$ SPLIT BYTE EIND $$$$$$
;############ LONG DELAY #########
longdly ;100 ms
movlw 0x1F ;;99998 cycles
movwf d1
movlw 0x4F
movwf d2
Delay_0
decfsz d1, f
goto $+2
decfsz d2, f
goto Delay_0
goto $+1 ;2 cycles
return
;$$$$$$$$$$$$ LONG DELAY END $$$$
loop
goto loop
endkeuninkske
!overload! to much information in this signature!
mijn eerste, vlugge indruk is dat 1 van je datalijnen naar massa getrokken wordt waardoor er geen 1 kan gestuurd worden op die lijn.
als je in het bezit bent van een scoop kun je dit mss even nagaan, anders mss toch eens het schema met 8 datalijnen proberen
helaas geen scoopje in huis, maar wanneer ik een pic basic programma er in druk zonder de aansluitingen te veranderen werkt alles prima. ik heb met opzet overal een extra lange delay van 100ms inzitten wat volgens mij zou moeten werken, en daarbij zou het in dat geval met de andere karakters ook niet moeten lukken
Was er bij die pruts-dingen van microchip niet 1 pin open collector? Zonder ook maar een blik op je code geworpen te hebben, gok ik erop dat je die voor data gebruikt en dat het daar dus de mist in gaat. Als ik je patroon zo zie, is dat waar je de LSB van de LCD aan hebt hangen. Zet daar eens een 4k7 pull-up en kijk eens of het dan beter gaat?
RB4 is open collector en daar zit een van jouw datalijnen op. Pull-up toevoegen en je bent er...
mmm.. zit even te denken: als je een 1 stuurt wordt de uitgang dan ook 1 met een pull-up of juist een 0? mja... kun je simpel uitproberen. 10k zou voldoende moeten zijn....
forget it but fripster! dat is RA4 en niet RB4. Zijn alle verbindingen A-OK? Geen tin die sluiting maakt?
fripster
edit: probeer de mijne eens, deze werkt zeker. www.machma.nl/data/serialLCD.zip
[Bericht gewijzigd door fripster op (10%)]
priegel priegel pfff pull-up op de LSB heeft niets uitgehaald
als ik ledjes ipv lcd aansluit werken alle verbindingen.
ik heb LVP uitstaan, dus zou RB4 gewoon beschikbaar moeten zijn voor I/O functies als ik het goed heb, als ik het niet goed heb hoor ik het graag
EDIT: bedankt fripster, ga eerst ff een biertje pakken dan de A poorten nogmaals proberen als het dan nog niet werkt ga ik even in een hoekje zitten huilen, en dan schuif ik jouw programma dr in
Ah, da's port A blijkbaar. Fripster heeft de code wel gelezen 
Anyway.. Ergens in die hoek zit je probleem. Je laagste bit wordt niet gestuurd. Rot contact, sluiting, whatever. Als je nou eens alleen maar characters stuurt waar die bit hoog is, dan zou je die zo moeten kunnen meten. Bij gebrek aan scoop met een LED. Doe hetzelfde met alleen characters sturen waar die bit laag is. Kun je in elk geval zien of die bit op de PCB van de LCD aan komt...
Als ik het wel heb, moet je de 4 niet gebruikte lijntjes van de LCD los laten hangen. Ik neem aan dat je dat gedaan hebt.
die hangen idd gewoon los, het hele zooitje zat op de B poorten, had het ook al op de A poorten geprobeerd maar daar het zelfde verhaal, zal dat zo voor zekerheid nogmaals de A poorten proberen
Eens een andere open deur...
Zet in software die PB4 eens hoog. Meet dan eens op de PCB van de LCD wat je daar hebt. Zit er geen rottigheid in je kabel ofzo?
Als je naar de init kijkt (nu toch even naar de code gekeken), dan zie je dat alle functions die je gebruikt die bit laag hebben (dan lukt het dus wel) op de clr na. Laat die clear nou overbodig zijn bij een nette power-on!
Overigens mis ik de reset nog, maar dat is een ander verhaal. Het lijkt mij sterk, maar zou het kunnen dat die LCD niet wil omdat de reset niet volgens spec verloopt? Heb daar niet zoveel ervaring mee, altijd netjes volgens datasheet gewerkt.
heb poort DB4 van het lcd nu aan poort A1 op de mcu en de rest op poort B, Nu werkt het verder prima.
toch raar, want poort RB4 werd wel netjes hoog en laag als ik hem door meet.
RB4 stuk, of heeft dat gekke ding toch nog stiekem andere functies?
Kijk in de datasheet, pag 41. Die LVP lijkt de enige te zijn die invloed heeft. Staat die echt uit? Ik zie het niet in je config staan. Of is dat default?
*me is toch weer blij met zijn keuze voor AVR
marco, je hebt het opgelost!! ik was er van overtuigd dat LVP uitstaat(heb ik altijd uitstaan). LVP staat standaard aan.
mijn dank is groot(niet zo groot als de bril die nodig heb)
STOM STOM STOM STOM STOM STOM STOM STOM STOM STOM STOM STOM STOM
[Bericht gewijzigd door Robbieeej op (16%)]
Kun jij dan wellicht mijn LCD probleem voor mij oplossen? Ik kan je vast vertellen dat een bril daar niet gaat helpen 
Nou ja, plezier ermee...
ghehe had t topic al gelezen.
heb een telescoop op mn jampot glazen geplakt, ik zie een naakte buurvrouw maar niet waar jij naar op zoek bent helaas.
in ieder geval nogmaals bedankt, en suc6 met je jouw lcd probleem!
Henry S.
Moderator
Confucius says chà bù duo. Deze post is niet door ChatGPT gegenereerd. De 2019 CO labvoeding.
Op 2 november 2009 21:11:10 schreef Robbieeej:
marco, je hebt het opgelost!! ik was er van overtuigd dat LVP uitstaat(heb ik altijd uitstaan). LVP staat standaard aan.
Je had B4 als uitgang gedefineerd... Rara.
is het een olifant? nee?
een broodrooster? ook niet?
geloof niet dat ik het ga raden ..
[Bericht gewijzigd door Henry S. op (39%)]
Henry S.
Moderator
Confucius says chà bù duo. Deze post is niet door ChatGPT gegenereerd. De 2019 CO labvoeding.
LVP is een ingang, dus dat mag geen invloed op een uitgang hebben. En volgens het blokschema is dat ook niet het geval.
The LVP bit is
normally erased to "1" which enables the low-voltage
programming. In this mode, the RB4/PGM pin is
dedicated to the programming function and ceases to
be a general purpose I/O pin.
If Low-Voltage Programming mode is not used, the
LVP bit should be programmed to a "0" so that RB4/
PGM becomes a digital I/O pin.
de RB4 poort is de pin voor LVP die ik gebruikt had als data lijn voor het lcd, als LVP uitstaat kan je die gewoon als digitale I/O gebruiken
Ik denk dat ik jouw opmerking niet helemaal snap
Henry S.
Moderator
Confucius says chà bù duo. Deze post is niet door ChatGPT gegenereerd. De 2019 CO labvoeding.
Dat kan kloppen, je bent een van de weinigen die de hele datasheet leest.
Het is idd de LVP flag die je poort B4 in de war schopt.
Niet stom, stom, stom van je, het staat op een vreemde plaats in de datasheet, men had het ook in chpt 5 moeten aanstippen.
hadv
Just find out what you like and let it kill you
Maar het staat toch (ook) in Chapter 5? Althans, ik heb twee datasheets, een 62X en een 628A-648A en in beide wordt het op meerdere plaatsen (ook chpt 5) genoemd. Maar het blijft een kwestie van zoeken-zoeken-zoeken, en je vindt het in de regel pas als je het weet. Want wie gaat er nou in een datasheet zoeken of RB4 wellicht door een fuse wordt beinvloed?
Toch verder geen kwaad woord over de datasheets van Microchip, ik vind ze best leesbaar en zeer informatief. Maar foutzoeken aan de hand van de datasheet is heel iets anders dan ontwerpen aan de hand van de datasheet (en dat laatste is in een aantal gevallen, zoals de 18F4550 ook al een hele klus).
Henry S.
Moderator
Confucius says chà bù duo. Deze post is niet door ChatGPT gegenereerd. De 2019 CO labvoeding.
Op 3 november 2009 00:56:11 schreef hadv:
Maar het staat toch (ook) in Chapter 5? Althans, ik heb twee datasheets, een 62X en een 628A-648A en in beide wordt het op meerdere plaatsen (ook chpt 5) genoemd.
in de 16F62xA datasheet DS40044 alleen tussen neus en lippen genoemd in Tabel 5.3
Maar het blijft een kwestie van zoeken-zoeken-zoeken, en je vindt het in de regel pas als je het weet. Want wie gaat er nou in een datasheet zoeken of RB4 wellicht door een fuse wordt beinvloed?
Via de genoemde tabel, maar als je daar overheen leest ga je.
Toch verder geen kwaad woord over de datasheets van Microchip, ik vind ze best leesbaar en zeer informatief.
Dat zijn ze zeker.
Maar foutzoeken aan de hand van de datasheet is heel iets anders dan ontwerpen aan de hand van de datasheet (en dat laatste is in een aantal gevallen, zoals de 18F4550 ook al een hele klus).
Of een 18F4520... daar moet je ingroeien.
Want wie gaat er nou in een datasheet zoeken of RB4 wellicht door een fuse wordt beinvloed?
Ik. Juist omdat microchip allemaal van dit soort rotgeintjes heeft. Reden genoeg om die pic-dingen dus gewoon niet te gebruiken: zoeken, zoeken, zoeken. Nog afgezien van dat rare gedoe met register banks.
Voordeel is wel dat de pdf reader het meeste zoekwerk gedaan heeft hoor 