Frequentieteller

25%:
-|    
 |___

50%:
--|
  |__

75%:
---|
   |_

Device = 16F628A

XTAL=20

Config HS_osc, CP_OFF, WDT_OFF, PWRTE_ON, LVP_OFF, MCLRE_OFF, BODEN_off 
DelayMS 50
ALL_DIGITAL=true
PORTB_PULLUPS=true

EData 0,0,0,"SUN","MON","TUE","WED","THU","FRI","SAT","JAN","FEB","MAR","APR","MAY","JUN","JUL","AUG","SEP","OCT","NOV","DEC"

Declare LCD_DTPIN PORTB.0
Declare LCD_RSPIN PORTA.0
Declare LCD_ENPIN PORTA.1
Declare LCD_LINES 2
Cls
Clear

Declare SCL_PIN PORTA.2
Declare SDA_PIN PORTA.3

Dim secs As Byte
Dim mins As Byte
Dim hrs As Byte
Dim weekday As Byte
Dim day As Byte
Dim month As Byte
Dim year As Byte
Dim dummy As Byte               ;dummy var for calculations
Dim temp As Word                ;temperature
Dim q As Byte                   ;loopcounter
Dim tablepos As Byte            ; position of the eeprom lookup table
Dim mode As Byte                ;mode 0= normal operation, everything else= setting by hand
Dim freq As DWord
Dim period As DWord
Dim highpulse As DWord
Dim duty As Byte
Dim teller As Byte

Clear                           ;reset all variables
TRISA=%11110000                        

Symbol modekey=PORTB.4
Symbol upkey=PORTB.5
Symbol downkey=PORTA.4
Symbol switch=PORTB.7
Set PIE1.0
Set INTCON.7
Set INTCON.6

on_interrupt GoTo isr

If switch=0 Then
    GoTo freq_counter
End If
GoTo clock

;------------------------------------------------------------------------------------
isr:
Clear PIR1.0
Inc teller
Context Restore
;--------------------------------------------------------------------------------------



;------------- initial start of RTC-oscillator
BusIn %11010001,0,[secs]             ;read seconds + bit7 (=osc. on/off)
DelayMS 10
Clear secs.7                         ; make sure osc. = on
BusOut %11010000,[secs]              ;write back to RTC
;-----------------------
BusIn %11010001,2,[hrs]             ;read hours
Clear hrs.6                         ;select 24 hr clock
BusOut %11010000,2,[hrs]            ;write back to rtc

BusOut %10010000,172,[1]            ;select oneshot mode in t-sensor.
BusOut %10010000,[238]              ;start a conversion
;-----------------------------


clock:
Cls
If mode=0 Then                      ;read RTC only if mode=0 (no change by hand)
    BusIn %11010001,0,[secs,mins,hrs,weekday,day,month,year]
    ;don't allow some values to be 0 when starting for the first time.
    If weekday=0 Then weekday=1
    If day=0 Then day=1
    If month=0 Then month=1

    ; because of the fact that each byte in the RTC is organised as a high nibble,
    ; containing the tens and a low nibble containing the singles, we have
    ; to manipulate the data a little. The tens are first masked, so we have
    ; nothing else than that.
    ; After that, we shift that value 4 bits to the righ, and we multiply it
    ; by 10 to get a good value. Then we add the singles to it.

    dummy=secs & %01110000                 ;bitwise AND
    GoSub calc_tens
    secs=secs & %00001111
    secs=secs+dummy
    dummy=mins & %11110000
    GoSub calc_tens
    mins=mins & %00001111
    mins=mins+dummy
    dummy=hrs & %00110000
    GoSub calc_tens
    hrs=hrs & %00001111
    hrs=hrs+dummy
    dummy=day & %11110000
    GoSub calc_tens
    day=day & %00001111
    day=day+dummy
    dummy=month & %11110000
    GoSub calc_tens
    month=month & %00001111
    month=month+dummy
    dummy=year & %11110000
    GoSub calc_tens
    year=year & %00001111
    year=year + dummy
End If
Print At 1,1,DEC2 hrs,":",DEC2 mins,":",DEC2 secs



Print $FE, $C0                      ;go to 2nd LCD-line
For q=0 To 2
    tablepos=weekday*3+q            ; mon, tue etc. have all 3 positons
    dummy=ERead tablepos            ;read 3 chars from eeprom table
    Print dummy
Next
Print At 2,5,DEC2 day," "
For q=0 To 2
    tablepos=month*3+21+q
    dummy=ERead tablepos
    Print dummy
Next
Print " 20",DEC2 year
If modekey=0 Then
    DelayMS 10
    Inc mode
    If mode>7 Then
        mode=0
        GoSub write_to_rtc          ;convert time/date values back to BCD and send to rtc
    End If
    Repeat                          ;wait until modekey is released
    Until modekey=1
End If
;---------- this part of the code is only executed when time/date must be set by hand.
If mode>0 Then                      
    DelayMS 300
    Select Case mode
        Case 1
            Print At 1,1,"  "
            DelayMS 300
            If upkey=0 Then
                DelayMS 10
                Inc hrs
                If hrs>23 Then
                    hrs=0
                End If
            End If
            If downkey=0 Then
                DelayMS 10
                Dec hrs
                If hrs>254 Then            ;in fact: <0
                    hrs=23
                End If
            End If
        Case 2
            Print At 1,4,"  "
            DelayMS 300
            If upkey=0 Then
                DelayMS 10
                Inc mins
                If mins>59 Then
                    mins=0
                End If
            End If
            If downkey=0 Then
                DelayMS 10
                Dec mins
                If mins>254 Then             ;<0
                    mins=59
                End If
            End If
        Case 3
            Print At 1,7,"  "
            DelayMS 300
            If upkey=0 Or downkey=0 Then
                DelayMS 10
                secs=0
            End If
        Case 4
            Print At 2,1,"   "
            DelayMS 300
            If upkey=0 Then
                DelayMS 10
                Inc weekday
                If weekday>7 Then
                    weekday=1
                End If
            End If
            If downkey=0 Then
                DelayMS 10
                Dec weekday
                If weekday<1 Then
                    weekday=7
                End If
            End If
        Case 5
            Print At 2,5,"  "
            DelayMS 300
            If upkey=0 Then
                DelayMS 10
                Inc day
                If day>31 Then
                    day=1
                End If
            End If
            If downkey=0 Then
                DelayMS 10
                Dec day
                If day<1 Then
                    day=31
                End If
            End If
        Case 6
            Print At 2,8,"   "
            DelayMS 300
            If upkey=0 Then
                DelayMS 10
                Inc month
                If month>12 Then
                    month=1
                End If
            End If
            If downkey=0 Then
                DelayMS 10
                Dec month
                If month<1 Then
                    month=12
                End If
            End If
        Case 7
            Print At 2,14,"  "
            DelayMS 300
            If upkey=0 Then
                DelayMS 10
                Inc year
                If year>99 Then
                    year=0
                End If
            End If
            If downkey=0 Then
                DelayMS 10
                Dec year
                If year<1 Then
                    year=99
                End If
            End If
    End Select
End If
If switch=0 Then
    Cls
    GoTo freq_counter
Else
    GoTo clock
End If


;----------------------------------------------------------------------------------------
calc_tens:
dummy=(dummy/16)*10               ;shift value 4 positions to the right & multiply by 10.
Return
;-----------------------------------------------------------------------------------------

write_to_rtc:

;convert time/date values back to BCD and write it to RTC

dummy=secs/10                 ;we only want the 10s here
dummy=dummy*16                ;shift that value to the high nibble
secs=secs//10                 ;for the singles we want the remainder of that division.
secs=secs | dummy             ;Bitwise OR to combine both values in 1 byte

dummy=mins/10
dummy=dummy*16
mins=mins//10
mins=mins | dummy

dummy=hrs/10
dummy=dummy*16
hrs=hrs//10
hrs=hrs | dummy

dummy=day/10
dummy=dummy*16
day=day//10
day=day | dummy

dummy=month/10
dummy=dummy*16
month=month//10
month=month | dummy

dummy=year/10
dummy=dummy*16
year=year//10
year=year | dummy

BusOut %11010000,0,[secs,mins,hrs,weekday,day,month,year]  ;write it al back to RTC


Return
;-------------------------------------------------------------------------------------


freq_counter:
teller=0 
T1CON=%00001010
TMR1H=0:TMR1L=0
Set T1CON.0
DelayMS 999
DelayUS 300
Clear T1CON.0
freq.BYTE1=TMR1H
freq.BYTE0=TMR1L
freq=teller*65536
freq=freq + (256 * TMR1H)
freq=freq + TMR1L
Print At 1,1,"FREQ: "
If freq>999999 Then
    Cls
    Print At 1,1,"OVERFLOW !"
Else
    Select Case freq
        Case>99999
            Print DEC6 freq
        Case 10000 To 99999
            Print " ",DEC5 freq
        Case 1000 To 9999
            Print "  ",DEC4 freq
        Case 100 To 999
            Print "    ",DEC3 freq
        Case 10 To 99
            Print "     ",DEC2 freq
        Case 0 To 9
            Print "      ",DEC1 freq
    End Select
    Print " Hz."
    period=1000000/freq
    teller=0
    T1CON=0
    TMR1H=0:TMR1L=0
    Repeat
    If switch=1 Then
        GoTo clock
    End If
    Until PORTA.5=0                     ;wachten tot signaal laag is.
    Repeat
    If switch=1 Then
        GoTo clock
    End If
    Until PORTA.5=1                     ;wachten tot signaal hoog is.
    T1CON=%00001001                     ;tellen kan beginnen. timer1=on
    Repeat                              ;wachten tot signaal weer laag is.
    Until PORTA.5=0
    T1CON=0                              ;timer1 uit.
    highpulse=teller*65536               ;berekenen.
    highpulse=highpulse + (256 * TMR1H)
    highpulse=highpulse + TMR1L
    highpulse=highpulse * 20 + 1
    duty=highpulse/period
    Print At 2,1,"DUTY-CYCLE : "
    Print DEC2 duty,"%"    
End If
If switch=0 Then
    GoTo freq_counter
Else
    Cls
    GoTo clock
End If